Listados de registros en Catalis

El siguiente formato puede ser utilizado para la generación de listados a partir de una base bibliográfica de Catalis.

Copie el bloque de texto en un archivo llamado listado.pft. Abra una ventana de comandos y ubíquese en la carpeta correspondiente a la base (p.ej. demo). Una vez allí, ejecute el comando

mx biblio pft=@listado.pft now > listado.txt

Eso generará un archivo llamado listado.txt, en esa misma carpeta.

Para obtener mx, se puede descargar junto con los restantes utilitarios CISIS.

/**
* Formato para generar listados a partir de las bases bibliográficas de Catalis.
* FG, 2007-11-06
*
* Uso:
* mx biblio pft=@listado.pft now > listado.txt
*
* Luego abrir listado.txt con una aplicación como Excel, indicando que se trata de texto delimitado por '|'.
*
* Comentarios, sugerencias: catalis@googlegroups.com
*/
lw(1000),
/* Número(s) de inventario */
(v859^p+|, |)
'|',
/* Título y mención de responsabilidad */
proc('a2450~',replace(v245*3, '^', '~a2450~'),'~'),
(
x1, v2450*1,
),
'|',
/* Datos de publicación */
proc('a2600~',replace(v260*3, '^', '~a2600~'),'~'),
(
x1, v2600*1,
),
'|',
/* Clasificación Dewey */
if p(v082) then v082^a, fi,
'|',
/* Punto de acceso principal */
if p(v100) then
proc('a1000~',replace(v100*3, '^', '~a1000~'),'~'),
fi,
if p(v110) then
proc('a1000~',replace(v110*3, '^', '~a1000~'),'~'),
fi,
if p(v111) then
proc('a1000~',replace(v111*3, '^', '~a1000~'),'~'),
fi,
(
x1, v1000*1,
),
'|',
/* Descriptores o encabezamientos de materia */
proc('d6500a6500~',replace(v650[1]*3, '^', '~a6500~'),'~'),
(
if iocc > 1 then '--', fi,
v6500*1,
),
if v650[2] > '' then
'|',
proc('d6500a6500~',replace(v650[2]*3, '^', '~a6500~'),'~'),
(
if iocc > 1 then '--', fi,
v6500*1,
),
fi
,/

Si prefiere, puede descargar el archivo comprimido (para Windows, codificación ANSI).