CatalisWiki

Esta página es de solo lectura. Puedes ver la fuente pero no puedes cambiarla. Pregunta a tu administrador si crees que esto es incorrecto.
====== Importación a MARC de datos de la biblioteca del MAC ======


<code>
/*
     mx seq=mac.txt create=mac now -all
     reemplazar en v3: coma => coma+espacio
     reemplazar en v3: espacio+espacio => espacio
     mx mac "proc='d3a3|',replace(v3,',',', '),'|'" "proc='d3a3|',replace(v3,'  ',' '),'|'" now -all copy=mac
     mxcp mac create=mac1 clean
     mx mac1 proc=@mac2marc.pft create=marcmarc now -all
     mx marcmarc "proc='d8a8~',replace(v8,' ','#'),'~'" copy=macmarc now -all

*/

'd*',

/* Fecha */
proc('a9003|',
    if val(right(v3,4)) > 1500 then
        right(v3,4),
    else
        '????',
    fi,
'|'),

/* Editorial */
proc('a9002|',
    if v3 : ', ' then
        mid(v3,1,instr(v3,', ')-1),
    else
        '[s.n.]',
    fi,
'|'),

/* Lugar */
/* si v3 sólo contiene una coma, entonces no hay lugar, sólo editor */
proc('a9001|',
    if s(replace(v3,v9002,'')) : ', ' then
        mid(v3, instr(v3,', ')+2, size(s(replace(v3,v9002,'')))-8),
    else
        '[S.l.]',
    fi,
'|'),

/*  /v9001 ' : ' v9002 ', ' v9003/#  */

'a001|',mfn(6),'|',
'a005|',s(date).8, s(date)*9.6,'.0','|',
'a008~',
    mid(date,3,6),
    if v9003 = '????' then
        'u########',
    else
        's',v9003,'####',
    fi
    x23,
    '||'
'~',

'a245|',
    '10^a',v2,
    if right(v2,1) <> '.' then '.', fi,
'|',

'a260|',
    '##',
    '^a',v9001,
    ' :^b',v9002,
    ',^c',v9003,
    '.',
'|',

'a300|',
    '##',
    '^ap.',
    ' :^bil.',
    ' ;^ccm.',
'|',

if p(v1) then
    if v1 : ', ' then
        'a700|',
            '1#',
            '^a',v1,
            if right(v1,1) <> '.' then '.', fi,
        '|',
    else
        'a710|',
            '2#',
            '^a',v1,
            if right(v1,1) <> '.' then '.', fi,
        '|',
    fi,
fi,
</code>